Currently,
R and
S must both be polynomial rings over the same base field.
This function first checks to see whether M will be a finitely generated R-module via F. If not, an error message describing the codimension of M/(vars of S)M is given (this is equal to the dimension of R if and only if M is a finitely generated R-module.
Assuming that it is, the push forward
F_*(M) is computed. This is done by first finding a presentation for
M in terms of a set of elements that generates
M as an
S-module, and then applying the routine
coimage to a map whose target is
M and whose source is a free module over
R.
Example: The Auslander-Buchsbaum formula
Let's illustrate the Auslander-Buchsbaum formula. First construct some rings and make a module of projective dimension 2.
i1 : R4 = ZZ/32003[a..d];
|
i2 : R5 = ZZ/32003[a..e];
|
i3 : R6 = ZZ/32003[a..f];
|
i4 : M = coker genericMatrix(R6,a,2,3)
o4 = cokernel | a c e |
| b d f |
2
o4 : R6-module, quotient of R6
|
i5 : pdim M
o5 = 2
|
Create ring maps.
i6 : G = map(R6,R5,{a+b+c+d+e+f,b,c,d,e})
o6 = map(R6,R5,{a + b + c + d + e + f, b, c, d, e})
o6 : RingMap R6 <--- R5
|
i7 : F = map(R5,R4,random(R5^1, R5^{4:-1}))
o7 = map(R5,R4,{15853a - 1101b + 174c - 856d + 3058e, - 3214a - 14448b + 6590c + 12982d - 3463e, - 3919a - 14267b + 3907c - 4523d + 10802e, 15148a - 10565b - 889c + 683d - 10762e})
o7 : RingMap R5 <--- R4
|
The module M, when thought of as an R5 or R4 module, has the same depth, but since depth M + pdim M = dim ring, the projective dimension will drop to 1, respectively 0, for these two rings.
i8 : P = pushForward(G,M)
o8 = cokernel | c -de |
| d bc-ad+bd+cd+d2+de |
2
o8 : R5-module, quotient of R5
|
i9 : pdim P
o9 = 1
|
i10 : Q = pushForward(F,P)
3
o10 = R4
o10 : R4-module, free, degrees {0..1, 0}
|
i11 : pdim Q
o11 = 0
|
Example: generic projection of a homogeneous coordinate ring
We compute the pushforward N of the homogeneous coordinate ring M of the twisted cubic curve in P^3.
i12 : P3 = QQ[a..d];
|
i13 : M = comodule monomialCurveIdeal(P3,{1,2,3})
o13 = cokernel | c2-bd bc-ad b2-ac |
1
o13 : P3-module, quotient of P3
|
The result is a module with the same codimension, degree and genus as the twisted cubic, but the support is a cubic in the plane, necessarily having one node.
i14 : P2 = QQ[a,b,c];
|
i15 : F = map(P3,P2,random(P3^1, P3^{-1,-1,-1}))
1 9 10 5 9 1 3 8 4
o15 = map(P3,P2,{-a + --b + 6c + d, --a + -b + c + -d, -a + -b + -c + -d})
2 10 3 3 4 2 2 5 3
o15 : RingMap P3 <--- P2
|
i16 : N = pushForward(F,M)
o16 = cokernel {0} | 7745706900ab-5935900752b2+94942329000ac+60845849460bc-288401560200c2 2151585250a2+359109648b2-14394513000ac-4061551980bc+23359512150c2 16981695951430935426912b3-545065341923857648010040b2c+5598928977390735093750000ac2+4600188879088510989795600bc2-17073342145492597462878000c3 0 |
{1} | -69099126005a-3245676588b+219458339835c 14963965590a+13976868892b-45399135075c 200867756973486490951625a2+319967704257802782336780ab+153498753480986552314728b2-3527049040971006718746700ac+603007192378213534825170bc+9448494855264896427272775c2 2711896625a3+2241599400a2b+807157008ab2-1492086528b3-841222875a2c+28427684400abc+18750132720b2c-70278086925ac2-106273014120bc2+145319117175c3 |
2
o16 : P2-module, quotient of P2
|
i17 : hilbertPolynomial M
o17 = - 2*P + 3*P
0 1
o17 : ProjectiveHilbertPolynomial
|
i18 : hilbertPolynomial N
o18 = - 2*P + 3*P
0 1
o18 : ProjectiveHilbertPolynomial
|
i19 : ann N
3 2 2 3
o19 = ideal(2711896625a + 2241599400a b + 807157008a*b - 1492086528b -
-----------------------------------------------------------------------
2 2 2
841222875a c + 28427684400a*b*c + 18750132720b c - 70278086925a*c -
-----------------------------------------------------------------------
2 3
106273014120b*c + 145319117175c )
o19 : Ideal of P2
|
Note: these examples are from the original Macaulay script by David Eisenbud.