This function produces a diagonal matrix
D, and invertible matrices
P and
Q such that
D = PMQ. Warning: even though this function is called the Smith normal form, it doesn't necessarily satisfy the more stringent condition that the diagonal entries
d1, d2, ..., dn of
D satisfy:
d1|d2|...|dn..
i1 : M = matrix{{1,2,3},{1,34,45},{2213,1123,6543},{0,0,0}}
o1 = | 1 2 3 |
| 1 34 45 |
| 2213 1123 6543 |
| 0 0 0 |
4 3
o1 : Matrix ZZ <--- ZZ
|
i2 : (D,P,Q) = smithNormalForm M
o2 = (| 135654 0 0 |, | 1 33471 -43292 0 |, | 171927 -42421 54868 |)
| 0 1 0 | | 0 1 0 0 | | 93042 -22957 29693 |
| 0 0 1 | | 0 0 1 0 | | -74119 18288 -23654 |
| 0 0 0 | | 0 0 0 1 |
o2 : Sequence
|
i3 : D == P * M * Q
o3 = true
|
i4 : (D,P) = smithNormalForm(M, ChangeMatrix=>{true,false})
o4 = (| 135654 0 0 |, | 1 33471 -43292 0 |)
| 0 1 0 | | 0 1 0 0 |
| 0 0 1 | | 0 0 1 0 |
| 0 0 0 | | 0 0 0 1 |
o4 : Sequence
|
i5 : D = smithNormalForm(M, ChangeMatrix=>{false,false}, KeepZeroes=>true)
o5 = | 135654 0 0 |
| 0 1 0 |
| 0 0 1 |
3 3
o5 : Matrix ZZ <--- ZZ
|
This function is the underlying routine used by minimalPresentation in the case when the ring is ZZ, or a polynomial ring in one variable over a field.
i6 : prune coker M
o6 = cokernel | 135654 |
| 0 |
2
o6 : ZZ-module, quotient of ZZ
|
In the following example, we test the result be checking that the entries of
D1, P1 M Q1 are the same. The degrees associated to these matrices do not match up, so a simple test of equality would return false.
i7 : S = ZZ/101[t]
o7 = S
o7 : PolynomialRing
|
i8 : D = diagonalMatrix{t^2+1, (t^2+1)^2, (t^2+1)^3, (t^2+1)^5}
o8 = | t2+1 0 0 0 |
| 0 t4+2t2+1 0 0 |
| 0 0 t6+3t4+3t2+1 0 |
| 0 0 0 t10+5t8+10t6+10t4+5t2+1 |
4 4
o8 : Matrix S <--- S
|
i9 : P = random(S^4, S^4)
o9 = | -42 -39 -19 40 |
| -42 -35 -43 0 |
| 10 -27 23 44 |
| 47 -3 36 10 |
4 4
o9 : Matrix S <--- S
|
i10 : Q = random(S^4, S^4)
o10 = | -36 -40 26 20 |
| 21 32 -33 19 |
| -2 -41 14 28 |
| 44 -11 -20 -7 |
4 4
o10 : Matrix S <--- S
|
i11 : M = P*D*Q
o11 = | 43t10+13t8-37t6+28t4+t2-34 -36t10+22t8+15t6+22t4+28t2-37
| -15t6+28t4-3t2-46 46t6+28t4-18t2
| 17t10-16t8+23t6-30t4-32t2-47 21t10+4t8-26t6-49t4-4t2+36
| 36t10-22t8-15t6-20t4-36t2+27 -9t10-45t8+50t6+32t4+20t2-27
-----------------------------------------------------------------------
8t10+40t8+16t6-37t4+17t2+38 23t10+14t8+t6+14t4+35t2+31 |
4t6-45t4+18t2-34 8t6-35t4-25t2+18 |
29t10+44t8+6t6+26t4+22t2-13 -5t10-25t8-12t6-45t4-30t2+23 |
2t10+10t8+19t6+15t4+13t2+9 31t10-47t8+5t6+45t4-35t2+3 |
4 4
o11 : Matrix S <--- S
|
i12 : (D1,P1,Q1) = smithNormalForm M;
|
i13 : D1 - P1*M*Q1 == 0
o13 = true
|
i14 : prune coker M
o14 = cokernel | t10+5t8+10t6+10t4+5t2+1 0 0 0 |
| 0 t6+3t4+3t2+1 0 0 |
| 0 0 t4+2t2+1 0 |
| 0 0 0 t2+1 |
4
o14 : S-module, quotient of S
|
This routine is under development. The main idea is to compute a Gröbner basis, transpose the generators, and repeat, until we encounter a matrix whose transpose is already a Gröbner basis. This may depend heavily on the monomial order.