pushForward(RingMap,Module)

Synopsis

Usage:
pushForward(F,M)
Function: pushForward
Inputs:
- F, a ring map, a ring map F: R --> S, graded
- M, a module, over S, graded
Optional inputs:
- MonomialOrder => default value Eliminate, the type of monomial ordering to use in the computation, as keyword, either Eliminate, ProductOrder, or Lex
- UseHilbertFunction => a Boolean value, default value true, whether to use the Hilbert function as a hint for the Gröbner basis computation, if M and F are homogeneous
- StopBeforeComputation => a Boolean value, default value false, see gb(..., StopBeforeComputation => ...)
- DegreeLimit => a Boolean value, default value {}, see gb(..., DegreeLimit => ...)
- PairLimit => a Boolean value, default value infinity, see gb(..., PairLimit => ...)
Outputs:
- a module, M, considered as an R-module

Description

Currently, R and S must both be polynomial rings over the same base field.

This function first checks to see whether M will be a finitely generated R-module via F. If not, an error message describing the codimension of M/(vars of S)M is given (this is equal to the dimension of R if and only if M is a finitely generated R-module.

Assuming that it is, the push forward F_*(M) is computed. This is done by first finding a presentation for M in terms of a set of elements that generates M as an S-module, and then applying the routine coimage to a map whose target is M and whose source is a free module over R.

Example: The Auslander-Buchsbaum formula

Let's illustrate the Auslander-Buchsbaum formula. First construct some rings and make a module of projective dimension 2.

i1 : R4 = ZZ/32003[a..d];

i2 : R5 = ZZ/32003[a..e];

i3 : R6 = ZZ/32003[a..f];

i4 : M = coker genericMatrix(R6,a,2,3)

o4 = cokernel | a c e |
              | b d f |

                              2
o4 : R6-module, quotient of R6

i5 : pdim M

o5 = 2

Create ring maps.

i6 : G = map(R6,R5,{a+b+c+d+e+f,b,c,d,e})

o6 = map(R6,R5,{a + b + c + d + e + f, b, c, d, e})

o6 : RingMap R6 <--- R5

i7 : F = map(R5,R4,random(R5^1, R5^{4:-1}))

o7 = map(R5,R4,{- 3736a - 1701b - 15835c + 12281d - 10648e, 5423a + 13836b - 2142c + 7245d + 5119e, - 4746a - 366b - 14290c - 4422d - 374e, - 10782a + 13358b + 3483c + 11588d - 10099e})

o7 : RingMap R5 <--- R4

The module M, when thought of as an R5 or R4 module, has the same depth, but since depth M + pdim M = dim ring, the projective dimension will drop to 1, respectively 0, for these two rings.

i8 : P = pushForward(G,M)

o8 = cokernel | c -de               |
              | d bc-ad+bd+cd+d2+de |

                              2
o8 : R5-module, quotient of R5

i9 : pdim P

o9 = 1

i10 : Q = pushForward(F,P)

        3
o10 = R4

o10 : R4-module, free, degrees {0..1, 0}

i11 : pdim Q

o11 = 0

Example: generic projection of a homogeneous coordinate ring

We compute the pushforward N of the homogeneous coordinate ring M of the twisted cubic curve in P^3.

i12 : P3 = QQ[a..d];

i13 : M = comodule monomialCurveIdeal(P3,{1,2,3})

o13 = cokernel | c2-bd bc-ad b2-ac |

                               1
o13 : P3-module, quotient of P3

The result is a module with the same codimension, degree and genus as the twisted cubic, but the support is a cubic in the plane, necessarily having one node.

i14 : P2 = QQ[a,b,c];

i15 : F = map(P3,P2,random(P3^1, P3^{-1,-1,-1}))

                 2         5    7   5    1    7    8        5    1    2
o15 = map(P3,P2,{-a + 2b + -c + -d, -a + -b + -c + -d, 2a + -b + -c + -d})
                 5         2    4   9    3    5    3        9    3    3

o15 : RingMap P3 <--- P2

i16 : N = pushForward(F,M)

o16 = cokernel {0} | 3424856422980ab+924001328880b2-899084234400ac-1749788812296bc+404303094630c2 159826633072400a2+314494934763600b2-38392885175460ac-444186891801000bc+100404174962196c2 96746822963789113563523572925800b3-165352935742512392101858977109500b2c-119486474164690397160794779500ac2+70728432484488870743630260431750bc2-8937795505443988078709975614725c3                                     0                                                                                                                                                                 |
               {1} | -14777802701200a+3148194092619b-1661087902170c                               -1186990062450780a+20043685128930b+131607750814431c                                      204580727830802022129090318294560a2-450900933638813735733457067690340ab+17704365505116901660564086481425b2+156323358017960138157792567767868ac+22565945460116278938161943498285bc-5653039381146314877195087380001c2 1255776860800a3-2428963496400a2b+1924382049300ab2-516568444200b3+406912348080a2c-2091399325020abc+1067261629500b2c+436910623272ac2-678485657340bc2+116964905661c3 |

                               2
o16 : P2-module, quotient of P2

i17 : hilbertPolynomial M

o17 = - 2*P  + 3*P
           0      1

o17 : ProjectiveHilbertPolynomial

i18 : hilbertPolynomial N

o18 = - 2*P  + 3*P
           0      1

o18 : ProjectiveHilbertPolynomial

i19 : ann N

                          3                 2                    2  
o19 = ideal(1255776860800a  - 2428963496400a b + 1924382049300a*b  -
      -----------------------------------------------------------------------
                   3                2                        
      516568444200b  + 406912348080a c - 2091399325020a*b*c +
      -----------------------------------------------------------------------
                    2                   2                  2  
      1067261629500b c + 436910623272a*c  - 678485657340b*c  +
      -----------------------------------------------------------------------
                   3
      116964905661c )

o19 : Ideal of P2

Note: these examples are from the original Macaulay script by David Eisenbud.

Caveat

The module M must be homogeneous, as must R, S, and f. If you need this function in more general situations, please write it and send it to the Macaulay2 authors, or ask them to write it!