This function produces a diagonal matrix
D, and invertible matrices
P and
Q such that
D = PMQ. Warning: even though this function is called the Smith normal form, it doesn't necessarily satisfy the more stringent condition that the diagonal entries
d1, d2, ..., dn of
D satisfy:
d1|d2|...|dn..
i1 : M = matrix{{1,2,3},{1,34,45},{2213,1123,6543},{0,0,0}}
o1 = | 1 2 3 |
| 1 34 45 |
| 2213 1123 6543 |
| 0 0 0 |
4 3
o1 : Matrix ZZ <--- ZZ
|
i2 : (D,P,Q) = smithNormalForm M
o2 = (| 135654 0 0 |, | 1 33471 -43292 0 |, | 171927 -42421 54868 |)
| 0 1 0 | | 0 1 0 0 | | 93042 -22957 29693 |
| 0 0 1 | | 0 0 1 0 | | -74119 18288 -23654 |
| 0 0 0 | | 0 0 0 1 |
o2 : Sequence
|
i3 : D == P * M * Q
o3 = true
|
i4 : (D,P) = smithNormalForm(M, ChangeMatrix=>{true,false})
o4 = (| 135654 0 0 |, | 1 33471 -43292 0 |)
| 0 1 0 | | 0 1 0 0 |
| 0 0 1 | | 0 0 1 0 |
| 0 0 0 | | 0 0 0 1 |
o4 : Sequence
|
i5 : D = smithNormalForm(M, ChangeMatrix=>{false,false}, KeepZeroes=>true)
o5 = | 135654 0 0 |
| 0 1 0 |
| 0 0 1 |
3 3
o5 : Matrix ZZ <--- ZZ
|
This function is the underlying routine used by minimalPresentation in the case when the ring is ZZ, or a polynomial ring in one variable over a field.
i6 : prune coker M
o6 = cokernel | 135654 |
| 0 |
2
o6 : ZZ-module, quotient of ZZ
|
In the following example, we test the result be checking that the entries of
D1, P1 M Q1 are the same. The degrees associated to these matrices do not match up, so a simple test of equality would return false.
i7 : S = ZZ/101[t]
o7 = S
o7 : PolynomialRing
|
i8 : D = diagonalMatrix{t^2+1, (t^2+1)^2, (t^2+1)^3, (t^2+1)^5}
o8 = | t2+1 0 0 0 |
| 0 t4+2t2+1 0 0 |
| 0 0 t6+3t4+3t2+1 0 |
| 0 0 0 t10+5t8+10t6+10t4+5t2+1 |
4 4
o8 : Matrix S <--- S
|
i9 : P = random(S^4, S^4)
o9 = | -28 11 -43 11 |
| -30 -16 28 -2 |
| 39 -43 -26 23 |
| -24 3 12 12 |
4 4
o9 : Matrix S <--- S
|
i10 : Q = random(S^4, S^4)
o10 = | 22 37 0 36 |
| -9 47 3 21 |
| 9 -40 19 -3 |
| -26 -2 0 12 |
4 4
o10 : Matrix S <--- S
|
i11 : M = P*D*Q
o11 = | 17t10-16t8-15t6+21t4+29t2+26 -22t10-9t8-15t6+3t4-2t2-33
| -49t10-43t8-36t6+6t4+38t2-10 4t10+20t8+31t6-32t4+5t2-49
| 8t10+40t8+48t6-33t4-40t2+9 -46t10-28t8-26t6+33t4-12t2+12
| -9t10-45t8+18t6+5t4+49 -24t10-19t8-13t6-24t4-45t2-39
-----------------------------------------------------------------------
-9t6+6t4+39t2+24 31t10-47t8+35t6+19t4-4t2-11 |
27t6+33t4-15t2-21 -24t10-19t8-21t6-20t4-3t2-9 |
11t6+5t4-23t2-17 -27t10-34t8+10t6-30t4+47 |
26t6-14t4-5t2+35 43t10+13t8-10t6-19t4-25t2+14 |
4 4
o11 : Matrix S <--- S
|
i12 : (D1,P1,Q1) = smithNormalForm M;
|
i13 : D1 - P1*M*Q1 == 0
o13 = true
|
i14 : prune coker M
o14 = cokernel | t10+5t8+10t6+10t4+5t2+1 0 0 0 |
| 0 t6+3t4+3t2+1 0 0 |
| 0 0 t4+2t2+1 0 |
| 0 0 0 t2+1 |
4
o14 : S-module, quotient of S
|
This routine is under development. The main idea is to compute a Gröbner basis, transpose the generators, and repeat, until we encounter a matrix whose transpose is already a Gröbner basis. This may depend heavily on the monomial order.